Perl array(@data) to variables($data)

Question

I am doing socket programming. The data ($ data) received from the socket contains 4 bytes of length data + json data. I want to trim the length and only parse the json.

I have completed the code and it works fine. But I wonder if there is a more efficient way (algorithm).

Is there an efficient way to move arrays to variables in perl?

@tmpp = split(//,$data); #data = socket data

my $t1 = sprintf("%02x%02x%02x%02x",ord($tmpp[0]),ord($tmpp[1]),ord($tmpp[2]),ord($tmpp[3])); 
$t1 = hex($t1); #t1 = length 

my $json;
my @tmp = @tmpp[0..-1];
foreach(@tmp){ $json .= $_;}<br>
print $json;

Ok Print ;

Are you following standard networking conventions, i.e. the sender converts the 32-bit from local endianess to network endianess before writing it to the socket? — Stefan Becker
– Stefan Becker, Commented Feb 6, 2019 at 16:31

Corion · Accepted Answer · 2019-02-06 16:28:38Z

2

This is a standard case for pack/unpack. The N/a template will unpack a string of length N (in network byte order):

my( $json ) = unpack 'N/a', $data;
print $json;

edited Feb 6, 2019 at 16:28

answered Feb 6, 2019 at 16:04

Corion

3,9151 gold badge20 silver badges27 bronze badges

Sign up to request clarification or add additional context in comments.

4 Comments

SAnji Holic Over a year ago

Thanks for letting me know. pack / unpack is the best choice. But it takes $ data as an argument. Is there a way to pack / unpack @data (array)?

Corion Over a year ago

@SAnjiHolic You already have $data as a string and keeping it that way is the most efficient approach. If you have an array, @tmpp, then unpack 'L>/a', join '', @tmpp could work and would be relatively fast. Splitting a string into an array and then working on the array is usually a bad approach in Perl.

Corion Over a year ago

@SanjiHolic If the answer works for you, please accept it ( stackoverflow.com/help/someone-answers )

Corion Over a year ago

@StefanBecker Thanks, N is a much better/clearer template

ikegami · Accepted Answer · 2019-02-06 17:54:48Z

If you have what you say you have, you could simply peel off the length prefix.

my $json = substr($data, 4);

But this would mean that the length prefix is useless, which suggests you have a major bug earlier in your program. Did you properly read from the socket?

sub read_bytes {
   my ($fh, $bytes_to_read) = @_;
   my $buf = '';
   while ($bytes_to_read) {
      my $bytes_read = read($fh, $buf, $bytes_to_read, length($buf))
      die($!) if !defined($bytes_read);
      die("Premature EOF") if !$bytes_read;
      $bytes_to_read -= $bytes_read;
   }

   return $buf;
}

sub read_uint32be { unpack('N', read_bytes($_[0], 4)) }

sub read_string {
   my ($fh) = @_;
   my $len = read_uint32be($fh);
   return read_bytes($fh, $len);
}

my $json = read_string($sock);

Collectives™ on Stack Overflow

Perl array(@data) to variables($data)

2 Answers 2

4 Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

4 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related