Using variable from another class as3

Question

i separated one big file into multiple file to have it cleaned and i got a problem now.

I have my main.as, character.as, camera.as.

What i'm trying to do is access a variable from another class which i set later on that class. Ill show you what i mean.

From my main.as im loading each class and add them as child so it get displayed on screen.

    public function buildGame()
    {
        var loadMap:Sprite = new nf_MapBuilder();
        var xChar:Sprite = new nf_Character();
        var xCam:Sprite = new nf_Camera();
        var UserControl:nf_UserControl = new nf_UserControl();

        addChild(loadMap);
        addChild(xChar);
        addChild(xCam);
        addChild(UserControl);
    }

Everything show on screen like it needed. Then it goes to my character.as:

package as3
{
import flash.display.Sprite;
import flash.events.Event;

public class nf_Character extends Sprite
{
    public var character_pos:Array = new Array();
    public var character_is_moving:Boolean = false;
    public var character_x_dir:int = 0;
    public var character_y_dir:int = 0;
    public var character:hero = new hero();

    public function nf_Character()
    {
        addEventListener(Event.ADDED_TO_STAGE,xCharLoad);
    }

    public function xCharLoad(e:Event)
    {
        character_pos = [2,2];
        character.x=64*(character_pos[1]);
        character.y=64*(character_pos[0]);
        addChild(character);
    }
}
}

There is the problem. I need to use those variable i set there in my character.as to use it in my camera.as:

package as3
{
import flash.display.Sprite;
import flash.events.Event;
import flash.geom.Rectangle;
import flash.display.StageScaleMode;

import as3.nf_Character;

public class nf_Camera extends Sprite
{
    private var xChar:nf_Character = new nf_Character();

    //Camera variables
    var stageW2:Number;
    var stageH2:Number;
    var view:Rectangle;

    public function nf_Camera()
    {
        addEventListener(Event.ADDED_TO_STAGE,xCamGo);
    }

    public function xCamGo(e:Event):void
    {
        trace("Camera pos - " + xChar.x + " " + xChar.character.y);

        view = new Rectangle(0,0,stage.stageWidth,stage.stageHeight)
        stageW2 = stage.stageWidth / 2 - 32;
        stageH2 = stage.stageHeight / 2 - 32;

        addEventListener(Event.ENTER_FRAME,CamView);
    }
    public function CamView(e:Event):void
    {
        view.x = xChar.character.x - stageW2;
        view.y = xChar.character.y - stageH2;
        scrollRect = view;
    }
}
}

When it was all in one big file it was ok i just had to set the variable in the class and acessing it trough every function but now im kinda confused. Anyone see how i could do this?

net.uk.sweet · Accepted Answer · 2013-05-05 00:52:55Z

1

In short, I think you should subscribe to an event from your character in your main class which is fired whenever the character moves. In the handler for that event you could call a method on the camera to set it's position according to the current position of the character.

main.as

private var xChar:Sprite = new nf_Character();
private var xCam:Sprite = new nf_Camera();

public function buildGame()
{
    var loadMap:Sprite = new nf_MapBuilder();
    var UserControl:nf_UserControl = new nf_UserControl();

    // listen for when the character has moved
    xChar.addEventListener(MoveEvent.MOVED, characterMovedHandler);

    addChild(loadMap);
    addChild(xChar);
    addChild(xCam);
    addChild(UserControl);
}

private function characterMovedHandler(event:MoveEvent):void
{
    xCam.setPosition(xChar.x, xChar.y);
}

nf_Character.as

public class nf_Character extends Sprite
{
    public var character_pos:Array = new Array();
    public var character_is_moving:Boolean = false;
    public var character_x_dir:int = 0;
    public var character_y_dir:int = 0;
    public var character:hero = new hero();

    public function nf_Character()
    {
        addEventListener(Event.ADDED_TO_STAGE,xCharLoad);
    }

    public function xCharLoad(e:Event)
    {
        character_pos = [2,2];
        character.x=64*(character_pos[1]);
        character.y=64*(character_pos[0]);
        addChild(character);
    }

    public function xCharMoved() 
    {
        // Dispatch a custom event when the character moves
        dispatchEvent(new MovedEvent(MovedEvent.MOVED)); 
    }
}

nf_Camera.as

public class nf_Camera extends Sprite
{
    private var xChar:nf_Character = new nf_Character();

    //Camera variables
    var stageW2:Number;
    var stageH2:Number;
    var view:Rectangle;

    public function nf_Camera()
    {
        addEventListener(Event.ADDED_TO_STAGE,xCamGo);
    }

    public function xCamGo(e:Event):void
    {
        trace("Camera pos - " + xChar.x + " " + xChar.character.y);

        view = new Rectangle(0,0,stage.stageWidth,stage.stageHeight)
        stageW2 = stage.stageWidth / 2 - 32;
        stageH2 = stage.stageHeight / 2 - 32;

        // Probably only need one enterframe either in your character class or main
        //addEventListener(Event.ENTER_FRAME,CamView);
    }
    public function setPosition(x:Number, y:Number):void
    {
        view.x = xChar.character.x - stageW2;
        view.y = xChar.character.y - stageH2;
        scrollRect = view;
    }
}

Out of interest, how are you moving the character?

answered May 5, 2013 at 0:52

net.uk.sweet

12.4k3 gold badges26 silver badges42 bronze badges

Sign up to request clarification or add additional context in comments.

4 Comments

Aenil Over a year ago

well im having the same problem with my character movement unless i addchild directly in my "usercontrol". Its strange tought cause i can retrieve my MapBuilder.as which construct the map and use some variable that are also used from the usercontrol and those work. Just not the character

Aenil Over a year ago

anyway ill check this tomorrow im too much confused to go on lol but thanks for your thing ill have a look at it.

net.uk.sweet Over a year ago

It sounds to me like you really need to separate all these entities (ie. they shouldn't need references to instances of the other entities) and have them communicating with some controller class (possibly main) via events.

Aenil Over a year ago

yup i used that other guy trick it was looking more simple but i also set everything in my main like you suggered so now i have my main controller which parse variable to instance instead of trying to get it from subclass to subclass.

bwroga · Accepted Answer · 2013-05-05 00:50:47Z

0

You can pass your character class instance to your camera class instance as an argument of the constructor. You will then have a reference to the character inside the camera class and you can access it's variables

// Inside buildGame() in main.
var xChar:nf_Character = new nf_Character();
var xCam:nf_Camera = new nf_Camera(xChar);

// Inside nf_Camera
public function nf_Camera(char:nf_Character) {
    xChar = char;
}

answered May 5, 2013 at 0:50

bwroga

5,4692 gold badges25 silver badges25 bronze badges

2 Comments

Aenil Over a year ago

wow that worked! I can now move and all is being called from my main like net.uk suggested. I also used your method bwroga to pass my variable to instance. This is the good way to go i think it look more clear to me. I still cant move the camera but ill get it to work now i can walk around :P

Aenil Over a year ago

it also repaired lot of thing actually, i had a trace going on in my camera and was seeing the trace 4 time when walking probably cause it was instantiated many time with all this spaghetti. With that i only see it once now like its suposed to be! Anyway, im happy! :P

Collectives™ on Stack Overflow

Using variable from another class as3

2 Answers 2

4 Comments

2 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

4 Comments

2 Comments

Your Answer

Sign up or log in

Post as a guest

Related