Read a variable from a different Class in Actionscript 3

Question

I have already set a variable in my document class "Main.as". I am now trying to access that variable and read its value from a different Class and Function, take that value and email it.

For example in my "Main.as" file I have this function:

public var _myVar:String;

function create() {
    _myVar = "hello";
}

Now from my other class "EmailtoFriend.as" I have a new function to try and get the value of that pre set variable:

function getVar() {
    trace(_myVar);
}

Why will it not output "hello"? Instead I get an error saying: Access of undefined property _myVar. If I could just get this simple example working, I think it will help me understand a lot of things. Thanks!

TM_ · Accepted Answer · 2012-01-31 20:42:02Z

1

The error your getting really says it all. Although _myVar is defined in your Main class public var _myVar:String;, it isn't defined in your Emailtofriend class. If you want access to _myVar you need to do one of the following:

Parse a reference of your Main object(using this) to your EmailToFriend class:

Main.as(document class):

package 
{
    import flash.display.Sprite;
    import flash.events.Event;

    public class Main extends Sprite 
    {
        public var _myVar:String;

        public function Main():void 
        {
            if (stage) init();
            else addEventListener(Event.ADDED_TO_STAGE, init);

        }// end function

        public function create():void
        {
            _myVar = "hello";

        }// end function

        private function init(e:Event = null):void 
        {
            removeEventListener(Event.ADDED_TO_STAGE, init);

            create();

            var emailToFriend:EmailToFriend = new EmailToFriend(this);
            emailToFriend.getVar();

        }// end function

    }// end class

}// end package

internal class EmailToFriend
{
    private var _main:Main;

    public function EmailToFriend(main:Main)
    {
        _main = main;

    }// end function

    public function getVar():void
    {
        trace(_main._myVar);

    }// end function

}// end class

Or to make _myVar a public static property of Main and access it via Main._myVar:

Main.as(document class):

package 
{
    import flash.display.Sprite;
    import flash.events.Event;

    public class Main extends Sprite 
    {
        public static var _myVar:String;

        public function Main():void 
        {
            if (stage) init();
            else addEventListener(Event.ADDED_TO_STAGE, init);

        }// end function

        public function create():void
        {
            _myVar = "hello";

        }// end function

        private function init(e:Event = null):void 
        {
            removeEventListener(Event.ADDED_TO_STAGE, init);

            create();

            var emailToFriend:EmailToFriend = new EmailToFriend();
            emailToFriend.getVar();

        }// end function

    }// end class

}// end package

internal class EmailToFriend
{
    public function EmailToFriend() {}

    public function getVar():void
    {
        trace(Main._myVar);

    }// end function

}// end class

Also one small thing, when using underscores for class properties, you should only use them for private properties, not public. Well I say only but I really mean it's more common.

[UPDATE]

This is in response to your comment:

Main.as:

package 
{
    import EmailToFriend;
    import flash.display.Sprite;
    import flash.events.Event;


    public class Main extends Sprite 
    {
        public static var _myVar:String;

        public function Main():void 
        {
            if (stage) init();
            else addEventListener(Event.ADDED_TO_STAGE, init);

        }// end function

        public function create():void
        {
            _myVar = "hello";

        }// end function

        private function init(e:Event = null):void 
        {
            removeEventListener(Event.ADDED_TO_STAGE, init);

            create();

            var emailToFriend:EmailToFriend = new EmailToFriend();
            emailToFriend.getVar();

        }// end function

    }// end class

}// end package

EmailToFriend.as:

package  
{
    import Main;

    public class EmailToFriend 
    {
        public function EmailToFriend() {}

        public function getVar():void
        {
            trace(Main._myVar);

        }// end function

    }// end class

}// end package

edited Jan 31, 2012 at 20:42

answered Jan 31, 2012 at 11:40

TM_

3,2072 gold badges19 silver badges15 bronze badges

Sign up to request clarification or add additional context in comments.

4 Comments

Brandon Over a year ago

Thanks for your help. I am assuming I need to put the internal class in my EmailtoFriend.as file? If so, I have done that and I am getting some errors: 1046: Type was not found or was not a compile-time constant: EmailToFriend. 1180: Call to a possibly undefined method EmailToFriend.

TM_ Over a year ago

@Brandon did you import your EmailToFriend class into your Main class? also did you remember to change internal to public?

Brandon Over a year ago

Yes, I have changed my EmailToFriend class to public, instead of internal and I also added "import EmailtoFriend;" underneath my other imports at the top of Main.as. I am getting the same 2 errors.

TM_ Over a year ago

@Brandon you must be doing something different, look at my updated answer.

Goran Mottram · Accepted Answer · 2012-01-31 11:59:43Z

1

All variables implicitly have a target, unless explicitly specified. Variables without an explicit target will commonly look in the local scope of the function (in this case, getVar()) and the global scope of the class (in this case, EmailToFriend).

I assume that these don't exist in your code, judging by the error. You will need something like the following to access the var:

function getVar() {
    var main:Main = new Main();
    main.create();
    trace(main._myVar);
}

edited Jan 31, 2012 at 11:59

answered Jan 30, 2012 at 14:32

Goran Mottram

6,30428 silver badges41 bronze badges

9 Comments

Brandon Over a year ago

Im getting an error "1009: Cannot access a property or method of a null object reference."

Goran Mottram Over a year ago

Which line is this error associated to? The object declaration or the trace? Also, are your objects in the same package?

Brandon Over a year ago

The error is occurring at line "var main:Main = new Main();" They are in the same package: package { public class Main extends MovieClip { public var _myVar:String; function create() { _myVar = "hello"; }

Brandon Over a year ago

Ok, Main and Emailtofriend are 2 separate packages/as files. Im sorry for my ignorance, but I am learning. So both of my as files are in my .fla root directory. "Path.To.Package.Main" I need to add this line to the top of my "EmailtoFriend" file? Where exactly does this go? After the package { ?

Goran Mottram Over a year ago

Odd, it should pick it up. For debugging purposes, try moving the class Main to a different package (and relative file location). Then use the import command at the top of Emailtofriend. If that import command errors, then it's something to do with the package declarations.

|

crooksy88 · Accepted Answer · 2012-01-30 14:58:35Z

0

Assuming Main.as is your document class:

public var _myVar:String;

public function create():String {
//we specify that this function will return a String using the :String in the above line

    //now give the variable a value
    _myVar = "hello";

    //and send it back to the caller of the function
    return _myVar;
}

Within your other class

function getVar():void {

    //MovieClip(root) is another way of referencing your document class.
    trace(MovieClip(root).create());
}

OR...

public var _myVar:String;

public function create():void {

    //now give the variable a value
    _myVar = "hello";

}

Within your other class

function getVar():void {

    //call the function that actually gives myVar a value
    MovieClip(root).create();

    //now you can trace the value
    trace(MovieClip(root)._myVar);
}

answered Jan 30, 2012 at 14:58

crooksy88

3,8511 gold badge26 silver badges31 bronze badges

1 Comment

Brandon Over a year ago

Ok, I am trying your example and I am getting an error- "Access of undefined property root" Here is my EmailtoFriend.as file: <code>package { import flash.display.*; public class EmailtoFriend { public function EmailtoFriend() { //trace("Email Loaded"); } public function getVar():void { //MovieClip(root) is another way of referencing your document class. trace(MovieClip(root).create()); } } }</code>

mgraph · Accepted Answer · 2012-01-30 14:58:38Z

0

  package {
    import flash.display.MovieClip;  
    public class Main extends MovieClip  {
       public var _myVar:String;
       public function Main(){
         create();
       }
       private function create() {
          _myVar = "hello";
         }
      }
      }
    }

in EmailtoFriend.a

import Main.as
var myMain = new Main();
trace(myMain._myVar);

edited Jan 30, 2012 at 14:58

answered Jan 30, 2012 at 14:30

mgraph

15.3k4 gold badges43 silver badges76 bronze badges

3 Comments

Brandon Over a year ago

Im getting an error "1009: Cannot access a property or method of a null object reference."

mgraph Over a year ago

in EmailtoFriend.as add import Main.as

Brandon Over a year ago

Here is my Main.as: package { import flash.display.*; import flash.events.*; public class Main extends MovieClip { public var _myVar:String; public function Main(){ var test:EmailtoFriend = new EmailtoFriend(); create(); } private function create() { _myVar = "hello"; } } } Here is my EmailtoFriend.as: package { public class EmailtoFriend { public function EmailtoFriend() { var myMain = new Main(); trace(myMain._myVar); } } } Im getting a "Stack Overflow" error

Jakir Hossen · Accepted Answer · 2014-04-14 14:52:01Z

What you should do is have a OOP approach, meaning use encapsulation in your classes. If you don;t know what that means, its ok. For instance, if you have a variable, that you want to be accessible, then you should really make it private, and the set up its own public function that returns the variable. Like this:

package {

public class SomeClass {
    private var someVar:Number = 12; // A private variable, which means only this class can
// use the reference someVar, and only other outiside classes can use the function getSomeVar.
    ... // skip some regular class stuff

    public function getSomeVar():Number {
        return this.someVar; //returns the variable someVar from this class to whoever is accessing it. 
//This function is public which means that anyone can call it and get the variable someVar.
    }
}
}

To access that variable, you just reference a class instance:

var someClass:SomeClass = new SomeClass(); // create the instance using the variable someClass
var myVar:Number = someClass.getSomeVar(); // ACCESSES the variable that you want from the class, 
//by first using the class instance reference, and then calling its public function that returns the value you want.

Collectives™ on Stack Overflow

Read a variable from a different Class in Actionscript 3

5 Answers 5

4 Comments

9 Comments

1 Comment

3 Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

5 Answers 5

4 Comments

9 Comments

1 Comment

3 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related