Parse multiple arrays in subroutine

Question

I have the below code

    use strict;
    sub test {
       my($greeting, @names) = @_;
       my $returnString;

       foreach my $name (@names) {
           $returnString .= "$greeting, $name!\n";
       }

       return $returnString;
    }
    print &test("Hi", "Tim", "Tom", "Chris");

which outputs

    Hi Tim! Hi Tom! Hi Chris!

I want to be able to add multiple arrays. I tried modifying my code like the below

       my(@greeting, @names) = @_;
       print &test("Hi", "Tim", "Hello", "Tom", "Bye", "Chris");

However I have found that this can't be done. From the reading I have done I think I need to pass the arguments as references.

        my($greeting, $names) = @_;
        my @names = $names;

But I have found this only outputs Hi Tim!

What is the best way to handle this situation?

Dave Sherohman · Accepted Answer · 2013-06-12 07:25:06Z

4

You do need to pass them as references for the sub to receive them as two separate arrays rather than a single list, you just got the syntax wrong. Try this instead:

my @greetings = qw( Hi Hello );
my @names = qw( Tim Tom Chris );

# Put a \ before the variable to get a reference to it
say_greetings(\@greetings, \@names);

sub say_greetings {
  my ($greeting_ref, $name_ref) = @_;

  # Put @ before an arrayref to get the array back
  my @greet = @$greeting_ref;
...
}

Also, you shouldn't get in the habit of prefixing sub calls with &. It's a holdover from Perl 4. In Perl 5, it's not required and can have unexpected side-effects.

answered Jun 12, 2013 at 7:25

Dave Sherohman

46.4k14 gold badges67 silver badges104 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

Zaid · Accepted Answer · 2013-06-12 07:36:08Z

The best way to handle this situation depends on your needs. Here are several options:

List::MoreUtils 'natatime' (if order matters)

use List::MoreUtils 'natatime';

test( 'Hi', 'Tim', 'Hi', 'Tom' );

sub test {

    warn( "Need to provide greeting-name pairs" ), # Check for
      return if @_ % 2;                            # data completeness

    my $iter = natatime, 2, @_;

    my $string;
    while ( my ( $greet, $name ) = $iter->() ) {

        $string .= "$greet $name!\n";
    }

    return $string;
}

Treat the list passed as a hash (if order doesn't matter):

test( 'Hi', 'Tim', 'Hi', 'Tom' );

sub test {

    my %set = @_;  # warnings pragma checks for
                   # data completeness during runtime

    return join "\n", map { "$_ $set{$_}!" } keys %set;
}

Pass key-value pairs as arrayrefs (preserves order, data completeness guaranteed):

test( [ 'Hi', 'Tim' ], [ 'Hi', 'Tom' ] );

sub test { join "\n", map { "@{$_}!" } @_ }

Sakthi Kumar · Accepted Answer · 2013-06-12 07:22:01Z

1

Hope this helps. If the greeting and names are always in order then the following code works.

use strict;

test("Hi", "Tim", "Hello", "Tom", "Bye", "Chris");

sub test
{
        my $i;
        my $len = @_;

        for ($i = 0; $i < @_; $i += 2) {
                print "$_[$i] $_[$i + 1]\n"
        }
}

Input validation is not done. Check for array length to be multiple of 2 would be good to go.

answered Jun 12, 2013 at 7:22

Sakthi Kumar

3,04517 silver badges28 bronze badges

Comments

mpapec · Accepted Answer · 2013-06-13 06:10:01Z

1

You don't have to use references, pass your list as it is and iterate over every second element as greeting and name are set in pairs.

use strict;
use warnings;

sub test {
   my @arg = @_;

   my $returnString = "";
   foreach my $i (grep { ! ($_%2) } 0 .. $#arg) {

       my ($greeting, $name) = @arg[$i, $i+1];
       $returnString .= "$greeting, $name!\n";
   }

   return $returnString;
}

print test("Hi", "Tim", "Hello", "Tom", "Bye", "Chris");

edited Jun 13, 2013 at 6:10

answered Jun 12, 2013 at 7:18

mpapec

50.7k8 gold badges71 silver badges133 bronze badges

Collectives™ on Stack Overflow

Parse multiple arrays in subroutine

4 Answers 4

Comments

Comments

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

4 Answers 4

Comments

Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related