Making one hash with array of Hashes

Question

I have recursively put together an array of hashes for perl, which looks something like this :

[
    {
        'Default' => {
            'Elect' => { 'P' => 1 }
        }
    },
    {
        'Default' => {
            'Elect' => { 'A' => 1 }
        }
    },
    {
        'Default' => {
            'Elect' => { 'M' => 1 }
        }
    },
    {
        'Default' => {
            'Elect' => { 'I' => 1 }
        }
    },
    {
        'Default' => {
            'Picker' => { 'L' => 1 }
        }
    },
]

My aim is to make this more condensed and look like a single hash, as compared to array of hashes. Is there anyway in which i can make this array of hashes look like a hash:

{
    'Default' =>{
        'Elect' =>{
            'P' => 1,
            'A' => 1,
            'M' => 1,
            'I' => 1,
        },
        'Picker' => {
            'L' => 1
        }
    }
}

Where are you getting the array of hashes from in the first place? We could certainly show you how to modify your array as you requested, but it might be better to build the proper data structure right from the beginning, if possible. — ThisSuitIsBlackNot
– ThisSuitIsBlackNot, Commented Mar 13, 2014 at 16:50

amon · Accepted Answer · 2014-03-13 16:57:12Z

2

Well, here is a simple recursive procedure to merge two hash references:

sub merge {
    my ($xs, $ys) = @_;
    while (my ($k, $v) = each %$ys) {
        if ('HASH' eq ref $v) {
            merge($xs->{$k} //= {}, $v);
        }
        else {
            $xs->{$k} = $v;
        }
    }
}

Then:

my $data = ...; # your input data structure
my $acc = {};
merge($acc, $_) for @$data;

which produces the result you desire in $acc.

There is also the Hash::Merge module, with that:

use Hash::Merge 'merge';
my $acc = {};
$acc = merge $acc, $_ for @$data;

answered Mar 13, 2014 at 16:57

amon

57.8k2 gold badges93 silver badges152 bronze badges

Sign up to request clarification or add additional context in comments.

3 Comments

user2583714 Over a year ago

You are almost right. the problem is that $xs gets re initialised everytime . So if you rather pass $_[0] instead of $xs it works perfect. Thanks

amon Over a year ago

@user2583714 I tested my code. It works just fine, because both inputs are references. Giving them names like $xs and $ys does not prevent correct functionality in this case, and makes the code much more comfortable to read.

user2583714 Over a year ago

Maybe i was doing something wrong . Working perfect for me , my way . Thanks a lot anyways

Collectives™ on Stack Overflow

Making one hash with array of Hashes

1 Answer 1

3 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

3 Comments

Your Answer

Sign up or log in

Post as a guest

Related