batch : Substring in loop with 2 variables

Question

I have a loop that loops over files, gets the actual file name (not including the whole path) and tries to check if that file name exists in some list. the code I have is:

setlocal enabledelayedexpansion enableextensions
for /R %%j in (*.c) do (
set MYVAR=%%j
set actualFileName=%%~nj
if NOT "%MY_FILE_LIST%"=="!MY_FILE_LIST:%actualFileName%=!" set "TOCOMPILE=!TOCOMPILE! %MYVAR%"

this code does not work since the actualFileName is accessed with % instead of !. but !MYVAR:~!actualFileName!! doesn't work either. what can i do?

possible duplicate of How to split the filename from a full path in batch? — Ondrej Tucny
– Ondrej Tucny, Commented May 10, 2015 at 9:55

MC ND · Accepted Answer · 2015-05-10 11:28:11Z

1

You can directly use the for replaceable parameter modifiers to get the needed information

for /r %%j in (*.c) do (
    echo actualFileName is %%~nj
)

Where %%~nj is the name, without extension, of the file being referenced in %%j. See for /? for the full list

edit to adapt to comments

setlocal enableextensions enabledelayedexpansion

for /r %%j in (*.c) do (
    if not "!MY_FILE_LIST:%%~nj!"=="%MY_FILE_LIST%" (
        set "TOCOMPILE=!TOCOMPILE! "%%~fj""
    )
)

This should do the job IF no file contains a exclamation in its name. If this can not be ensured

setlocal enableextensions disabledelayedexpansion
for /r %%j in (*.c) do (
    setlocal enabledelayedexpansion
    if not "!MY_FILE_LIST:%%~nj!"=="%MY_FILE_LIST%" (
        for /f "delims=" %%a in ("!TOCOMPILE! ") do (
            endlocal
            set "TOCOMPILE=%%a"%%~fj""
        )
    ) else endlocal
)

edited May 10, 2015 at 11:28

answered May 10, 2015 at 9:55

MC ND

71.1k8 gold badges95 silver badges136 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

one Over a year ago

thanks for that!, but my issue now is at the next step. i've edited the question.

npocmaka · Accepted Answer · 2015-05-10 09:55:44Z

1

setlocal enabledelayedexpansion enableextensions
for /R %%j in (*.c) do (
 set MYVAR=%%j
 set lastIndex= some calculation to find last index of /


 for /f "tokens=* delims=" %%# in ("!lastIndex!") do (
    set actualFileName=!MYVAR:~%%#!
 )

)

use another nested FOR

answered May 10, 2015 at 9:55

npocmaka

57.8k19 gold badges162 silver badges199 bronze badges

Collectives™ on Stack Overflow

batch : Substring in loop with 2 variables

2 Answers 2

1 Comment

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

1 Comment

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related