Delphi How to get default value for property using RTTI

Question

If I have a class like this:

TServerSettings = class(TSettings)
strict private
    FHTTPPort : Integer;
published
    property HTTPPort : Integer read FHTTPPort write FHTTPPort default 80;
end;

How can I get the default attribute of the HTTPPort property using RTTI?

There are both... Just remember my comment and do not blame me when you'll be doing something deeper and the old RTTI won't suffice :-) — TLama
– TLama, Commented May 20, 2015 at 14:42
The default you're using doesn't mean what you think it does. It's a storage specifier. It only decides whether or not the property is streamed to the DFM at designtime. (In this case, if the HTTPPort property is 80 when the .DFM is streamed, the HTTPPort property is not saved.) See the Storage Specifiers section: Note: Property values are not automatically initialized to the default value. That is, the default directive controls only when property values are saved to the form file... — Ken White
– Ken White, Commented May 20, 2015 at 14:46

RRUZ · Accepted Answer · 2015-05-20 14:46:07Z

4

You can use the Default property of the TRttiInstanceProperty class

{$APPTYPE CONSOLE}

{$R *.res}

uses
  Rtti,
  System.SysUtils;


type
  TServerSettings = class
  strict private
      FHTTPPort : Integer;
  published
      property HTTPPort : Integer read FHTTPPort write FHTTPPort default 80;
  end;

var
   L : TRttiType;
   P : TRttiProperty;
begin
  try
     P:= TRttiContext.Create.GetType(TServerSettings.ClassInfo).GetProperty('HTTPPort');
     if P is TRttiInstanceProperty  then
       Writeln(TRttiInstanceProperty(P).Default);
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
  Readln;
end.

answered May 20, 2015 at 14:46

RRUZ

137k20 gold badges365 silver badges489 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

David Heffernan · Accepted Answer · 2015-05-20 14:56:43Z

3

Like this:

{$APPTYPE CONSOLE}

uses
  System.TypInfo;

type
  TMyClass = class
  strict private
    FMyValue: Integer;
  published
    property MyValue: Integer read FMyValue default 42;
  end;

var
  obj: TMyClass;
  PropInfo: PPropInfo;

begin
  obj := TMyClass.Create;
  PropInfo := GetPropInfo(obj, 'MyValue');
  Writeln(PropInfo.Default);
end.

Note that the class as it stands, just as is so for that in your question, is broken. The system will not automatically initialise properties to their default value when an instance is created. You would need to add a constructor to this class to do that.

edited May 20, 2015 at 14:56

answered May 20, 2015 at 14:35

David Heffernan

616k46 gold badges1.1k silver badges1.5k bronze badges

2 Comments

fnkr Over a year ago

Thanks that works but what if MyValue is not an integer but a bool or so? Then I get something like incompatible type boolean and integer.

David Heffernan Over a year ago

You'll have to cast it. Default property values are only available for ordinal properties. So, for a boolean, 0 means false, 1 means true.

Collectives™ on Stack Overflow

Delphi How to get default value for property using RTTI

2 Answers 2

Comments

2 Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

Comments

2 Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related