Convert array of arrays to array of hash

Question

I have following array of arrays in Perl that are getting as multiple rows in database.

$arrayref = [
    [ 1, "name1",  "name2" ],
    [ 2, "name3",  undef ],
    [ 3, "name5",  "name6" ],
    [ 4, "name10", undef ],
];

I want to make this as an array of hashes like this

my @array = (
    { id => 1, name => "name1",  l_name => "name2" },
    { id => 2, name => "name3",  l_name => undef },
    { id => 3, name => "name5",  l_name => "name6" },
    { id => 4, name => "name10", l_name => undef },
);

Where do you get your data for your array? Is parsing it into a hash upstream (rather than converting it later) an option? — Sobrique
– Sobrique, Commented Aug 13, 2015 at 12:15

ikegami · Accepted Answer · 2015-08-13 13:33:58Z

8

You can use map {} to transform array references to hash references,

my @cols = qw(id name l_name);

my @array = map { my %h; @h{@cols} = @$_; \%h } @$arrayref;

or

use List::MoreUtils qw( zip );

my @cols = qw(id name l_name);

my @array = zip(\@cols, @$arrayref);

edited Aug 13, 2015 at 13:33

ikegami

391k17 gold badges291 silver badges555 bronze badges

answered Aug 13, 2015 at 12:09

mpapec

50.7k8 gold badges71 silver badges133 bronze badges

Sign up to request clarification or add additional context in comments.

3 Comments

Sobrique Over a year ago

Oh that's very elegant. I like it.

Futuregeek Over a year ago

yes it is. Thanks for that solution. The one i made was a lengthy code

Sinan Ünür Over a year ago

While this solves the OP's immediate problem, @Borodin's answer solves the real issue.

Borodin · Accepted Answer · 2015-08-13 12:30:28Z

8

I have following array of arrays in Perl that are getting as multiple rows in database

You are presumably calling

$sth->fetchall_arrayref();

If instead you use an empty anonymous hash as the first parameter

$sth->fetchall_arrayref( {} );

then DBI will return the data in the format you want as an array of hashes

The DBI documentation describes it here

If $slice is a hash reference, fetchall_arrayref fetches each row as a hash reference. If the $slice hash is empty then the keys in the hashes have whatever name lettercase is returned by default. (See FetchHashKeyName attribute.) If the $slice hash is not empty, then it is used as a slice to select individual columns by name. The values of the hash should be set to 1. The key names of the returned hashes match the letter case of the names in the parameter hash, regardless of the FetchHashKeyName attribute.

For example, to fetch all fields of every row as a hash ref:
$tbl_ary_ref = $sth->fetchall_arrayref({});

edited Aug 13, 2015 at 12:30

answered Aug 13, 2015 at 12:21

Borodin

127k9 gold badges72 silver badges146 bronze badges

2 Comments

simbabque Over a year ago

Could you add a link to the DBI documentation? I've never seen that feature.

Borodin Over a year ago

@simbabque: Sure, but it's only the fetchall_arrayref documentation

Collectives™ on Stack Overflow

Convert array of arrays to array of hash

2 Answers 2

3 Comments

2 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

3 Comments

2 Comments

Your Answer

Sign up or log in

Post as a guest

Related