Perl - why does my assignment from an array ref give an error

Question

Fragment A below works, copying an array by dereferencing an array ref.

Fragment B, deeper in some real code, does not. The commented-out line is not part of the real code, which works fine (%ips is a hash in which each key is an IP address and each value is a reference to an array).

But why does the commented-out line fail with the message

Global symbol "$ips" requires explicit package name at ...

Fragment A:

my $a1 = [1,2,3];
say $$a1[1];
my @a2 = @$a1;
say "@a2";

Fragment B:

    else {
            # Initialise count to 1, 
            # set both dates:
        $ips{$1} = [1, $2, $2];
        # my @arr = @$ips{$1};  # error...
    }

Greatly obleeged to the answerers, {$ips{$1}}; works fine. But I'm puzzled that ($ips{$1}); (round instead of curly) fails. I'll try to find out why by RTFM...:-) @J-L — John White
– John White, Commented Oct 2, 2017 at 12:13

mpapec · Accepted Answer · 2017-09-30 11:31:17Z

3

Perl is looking for $ips variable as you've made mistake when dereferencing %ips hash. You can

my @arr = @{ $ips{$1} };

or

my $ref = $ips{$1};
my @arr = @$ref; # or @{ $ref }

answered Sep 30, 2017 at 11:31

mpapec

50.7k8 gold badges71 silver badges133 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

J-L · Accepted Answer · 2017-09-30 16:37:05Z

2

The problem with using code like:

@$ips{$1}

is that you think that "@" is dereferencing "$ips{$1}" (so it can be assigned to an array), but in reality that line is using "{$1}" to get an element from "@$ips".

The "@" and "$" sigils bind more tightly than "{$1}" does, so the above is closer to:

(@$ips) {$1}

than what you want, which is:

@ ($ips{$1})

To overcome this, you can tell Perl to have the "@" sigil work on "$ips{$1}" by putting "$ips{$1}" in curly brackets, like this:

@{$ips{$1}}

This way, there's no ambiguity over which happens first.

answered Sep 30, 2017 at 16:37

J-L

1,96113 silver badges17 bronze badges

Comments

ikegami · Accepted Answer · 2017-09-30 21:33:55Z

@$ips{$1}

is short for

@{ $ips }{$1}     # Hash slice, like @hash{"a", "b", "c"}

but you want

@{ $ips{$1} }     # Array, like @array

Scalar         Direct           $NAME         $scalar
Scalar         By ref (simple)  $$NAME        $$scalar_ref
Scalar         By ref           $BLOCK        ${ $scalar_ref }

Array          Direct           @NAME         @array
Array          By ref (simple)  @$NAME        @$array_ref
Array          By ref           @BLOCK        @{ $array_ref }

Hash           Direct           %NAME         %hash
Hash           By ref (simple)  %$NAME        %$hash_ref
Hash           By ref           %BLOCK        %{ $hash_ref }

Hash element   Direct           $NAME{EXPR}   $hash{key}
Hash element   By ref (simple)  $$NAME{EXPR}  $$hash_ref{key}
Hash element   By ref           $BLOCK{EXPR}  ${ $hash_ref }{key}

Hash slice     Direct           @NAME{LIST}   @hash{qw( a b c )}
Hash slice     By ref (simple)  @$NAME{LIST}  @$hash_ref{qw( a b c )}
Hash slice     By ref           @BLOCK{LIST}  @{ $hash_ref }{qw( a b c )}

Array element  Direct           $NAME[EXPR]   $array[3]
Array element  By ref (simple)  $$NAME[EXPR]  $$array_ref[3]
Array element  By ref           $BLOCK[EXPR]  ${ $array_ref }[3]

Array slice    Direct           @NAME[LIST]   @array[3..5]
Array slice    By ref (simple)  @$NAME[LIST]  @$array_ref[3..5]
Array slice    By ref           @BLOCK[LIST]  @{ $array_ref }[3..5]

Collectives™ on Stack Overflow

Perl - why does my assignment from an array ref give an error

Fragment A:

Fragment B:

3 Answers 3

Comments

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

Fragment A:

Fragment B:

3 Answers 3

Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related