Why "Not an ARRAY reference" error?

Question

I have this script

#!/usr/bin/perl

use strict;
use warnings;

use yy;

my $data = [
    ["aax", "ert", "ddd"],
    ["asx", "eer", "kkk"],
    ["xkk", "fff", "lll"],
    ["xxj", "vtt", "lle"],
    ];

use Test::More tests => 4;

is(yy::type1_to_type2(\$data, 'aax'), 'ert');
is(yy::type1_to_type3(\$data, 'asx'), 'kkk');
is(yy::type2_to_type3(\$data, 'fff'), 'lll');
is(yy::type3_to_type1(\$data, 'lle'), 'xxj');

which uses this module

package yy;

sub typeX_to_typeY {
    my ($x, $y, $data, $str) = @_;

    foreach (@$data) {
    if ($_->[$x - 1] eq $str) {
        return $_->[$y - 1];
    }
    }

    return;
}

sub type1_to_type2 { typeX_to_typeY(1, 2, @_) }
sub type1_to_type3 { typeX_to_typeY(1, 3, @_) }
sub type2_to_type1 { typeX_to_typeY(2, 1, @_) }
sub type2_to_type3 { typeX_to_typeY(2, 3, @_) }
sub type3_to_type1 { typeX_to_typeY(3, 1, @_) }
sub type3_to_type2 { typeX_to_typeY(3, 2, @_) }

1;

and gives this error

Not an ARRAY reference at yy.pm line 6.
# Looks like your test died before it could output anything.

The line it complains about is

foreach (@$data) {

Isn't this the way to pass an array reference?

What am I doing wrong?

a'r · Accepted Answer · 2011-03-14 16:19:08Z

14

You are creating a reference to a reference as $data is already an array reference - firstly, it is a scalar and secondly you used square brackets to initialise its value. So, change your calls to use $data rather than \$data.

edited Mar 14, 2011 at 16:19

answered Mar 14, 2011 at 16:10

a'r

37.2k7 gold badges68 silver badges67 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

Eugene Yarmash · Accepted Answer · 2011-03-14 16:12:08Z

7

$data = [] is a reference to array. By using \$data you create a reference to a scalar.
Change the code to be:

is(yy::type1_to_type2($data, 'aax'), 'ert');
...

answered Mar 14, 2011 at 16:12

Eugene Yarmash

152k44 gold badges346 silver badges391 bronze badges

Collectives™ on Stack Overflow

Why "Not an ARRAY reference" error?

2 Answers 2

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related