Parsing argument which is a comma separated string, passed to a batch file

Question

I have a batch file that takes one argument which is a comma separated string and I'm calling it like this:

myBatch.bat ".git,*.tmp,file.c"

Inside the batch file I need to write a code that parses the argument that is passed at the command line and break it like this:

@echo off
set excludes=%~1
set excludes_cmd=""

FOR /f "tokens=1* delims=," %%a IN ("%excludes%") DO (
   set "excludes_cmd=%%excludes_cmd%% --exclude %%~a"
)

So at the end, when I pring the 'excludes_cmd' variable I will get this:

--exclude .git --exclude *.tmp --exclude file.c

If you are going to use a FOR /F then you need to know how many tokens you will have passed to the script. In your case it is three, so you would be using tokens=1-3 and %%a , %%b and %%c. But you would be better off using a normal FOR command. FOR %%a in (%~1) DO (call set "excludes_cmd=%%excludes_cmd%% --exclude %%~a" — Squashman
– Squashman, Commented Apr 11, 2019 at 15:01
@Squashman, a standard for loop will resolve wildcards like * and ?, but I believe this is not what the OP wants... — aschipfl
– aschipfl, Commented Apr 12, 2019 at 10:56
This seems not to be an easy task in pure batch scripting: for resolves wildcards (*, ?), for /F needs a predefined number of items (tokens), sub-string replacement does not care about quotation (I guess there could also occur quoted strings like '.txt' in the argument, which could even contain , on their own, like 'x,y'; right? such commas need to be preserved then)... — aschipfl
– aschipfl, Commented Apr 12, 2019 at 11:07

Compo · Accepted Answer · 2019-04-11 15:44:11Z

2

You should be able to do this with basic variable expansion and substitution:

@Echo Off
Set "excludes=%~1"
If Not Defined excludes GoTo :EOF
Set "excludes_cmd=--exclude %excludes:,= --exclude %"

The variable, %excludes_cmd%, should contain your required content.

answered Apr 11, 2019 at 15:44

Compo

39k5 gold badges32 silver badges46 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

user6811411 · Accepted Answer · 2019-04-11 15:54:03Z

2

Came up with a similar way as Compo, just inserting your examples as defaults.

@echo off
if "%~1"=="" "%~f0" ".git,*.tmp,file.c"
set "excludes=,%~1"
set "excludes_cmd=%excludes:,= --exclude %"
set excludes

excludes=,.git,*.tmp,file.c
excludes_cmd= --exclude .git --exclude *.tmp --exclude file.c

answered Apr 11, 2019 at 15:54

user6811411

Collectives™ on Stack Overflow

Parsing argument which is a comma separated string, passed to a batch file

2 Answers 2

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related