Read parameters using variables

Question

I have a problem reading parameters that have been added to a subroutine. These parameters can of course be read in the following way.

call :test one two three

:test
    echo %1
    echo %2
    echo %3
exit /b

But I would like to read it in a loop as long as they are filled.

I made the following for that, but I don't get it working properly. With my limited understanding of all this. I would normally request a variable on the 3 dots. So %p%.

call :test one two three

:test
    set /a p=1

    :while
    if [%...] NEQ [] (
        echo %...
        set /a p=p+1
    goto :while
    )
exit /b

Can someone tell me how I solve this?

or if it's just to echo the parameters line by line, all you need in the :test subroutine is for %%a in (%*) do echo %%a (where %* is a list of "all parameters") — Stephan
– Stephan, Commented Sep 21, 2019 at 16:43
This must be a duplicate question, but I am too burnt out to go and find one with a good answer. — jwdonahue
– jwdonahue, Commented Sep 21, 2019 at 18:35
You need to put exit /B after the call command line to not continue execution unintentionally... — aschipfl
– aschipfl, Commented Sep 21, 2019 at 21:48

Paul · Accepted Answer · 2019-09-23 07:27:59Z

1

Thanks @Stephan. It works just like i want :

:test
for %%A in (%*) do (
    echo %%A
)
exit /b

edited Sep 23, 2019 at 7:27

user9556248

answered Sep 22, 2019 at 9:25

Paul

112 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

Stephan Over a year ago

Please accept the answer that solved your issue (even if it's your own) to remove this question from the "unanswered" queue.

Magoo · Accepted Answer · 2019-09-21 16:39:06Z

@ECHO OFF
SETLOCAL
call :test one two three
call :test four five
call :test seven eight nine ten
CALL :test
goto :eof

:test
rem for /f "delims==" %%a in ('set parm 2^>nul') do set "%%a="
set /a parmcnt=0
:testlp
set /a parmcnt+=1
SET "parm%parmcnt%=%1"
SHIFT
IF DEFINED parm%parmcnt% GOTO testlp
SET /a parmcnt-=1
ECHO %parmcnt% parameters
IF %parmcnt% gtr 0 FOR /L %%a IN (1,1,%parmcnt%) DO CALL ECHO %%parm%%a%%
ECHO -------------------
SET parm
ECHO ===================
GOTO :EOF

The meat here is the :testlp loop. The parameter count parmcnt is incremented, and the variable parm... is set to %1 - the first parameter, then the paramter list is SHIFTed which simply removes the first parameter from the apparent list.

if the parm... has a value, then try again, until all of the parameters have been assigned to parm*

decrement the parameter count (since the last assignment attempt assigned a value of nothing as %1 did not exist) and display the results.

The result-display is in two parts. The first uses a parsing trick (to avoid delayed expansion which is a whole new ball-game). The parser first substitutes for the metavariable %%a, so what is executed is call echo %%parm1%% etc. for 1 to %parmcnt%. calling the echo executes echo %parm1% in a subshell.

The second simply shows all variables set which start parm. Note that parm%parmcnt+1% will always be empty, but there may be stray parms set from prior invocations of :test

Hence the remmed-out for ... set parm line which clears all variables starting parm. Removing the rem from this line would dispose of the stray variables problem, but note that it would also clear any variablename that starts parm - like parmlimit had parmlimit been set.

I like @stephan's for %%a in (%*) do echo %%a suggestion. It's a simpler, more direct answer to the OP's question.

Collectives™ on Stack Overflow

Read parameters using variables

2 Answers 2

1 Comment

1 Comment

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

1 Comment

1 Comment

Your Answer

Sign up or log in

Post as a guest

Related