Replace value in a node retaining the XML Structure using XSLT

Question

I have a requirement where I need to replace the value of a node based on the attributes with a different value, retaining the original XML structure. Basically, I need to copy the whole XML only by replacing certain values when specific attributes are encountered in the original XML.

Below is a sample XML before transformation and after transformation.

Original XML:

<root>
    <body>
        <node_level1>
            <node_level2>
                <node_level3>
                    <value animal="cat">Munchkin</value>
                </node_level3>
                <node_level3>
                    <value animal="cat">Turkish Angora</value>
                </node_level3>
                <node_level3>
                    <value animal="cat">La Perm</value>
                </node_level3>
            </node_level2>
            <node_level2>
                <node_level3>
                    <node_level4>
                        <value animal="dog">Siberian Husky</value>
                    </node_level4>
                    <node_level4>
                        <value animal="dog">Pug</value>
                    </node_level4>
                    <node_level4>
                        <value animal="dog">Beagle</value>
                    </node_level4>
                </node_level3>
            </node_level2>
        </node_level1>
    </body>
</root>

After transforming the data using XSLT, I need the XML as below:

<root>
    <body>
        <node_level1>
            <node_level2>
                <node_level3>
                    <value animal="cat">Cat Family</value>
                </node_level3>
                <node_level3>
                    <value animal="cat">Cat Family</value>
                </node_level3>
                <node_level3>
                    <value animal="cat">Cat Family</value>
                </node_level3>
            </node_level2>
            <node_level2>
                <node_level3>
                    <node_level4>
                        <value animal="dog">Dog Family</value>
                    </node_level4>
                    <node_level4>
                        <value animal="dog">Dog Family</value>
                    </node_level4>
                    <node_level4>
                        <value animal="dog">Dog Family</value>
                    </node_level4>
                </node_level3>
            </node_level2>
        </node_level1>
    </body>
</root>

Here is the code that works for specified attributes, I need to generalize it.

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" exclude-result-prefixes="xsl" version="2.0">
    <xsl:template match="/">
        <root>
            <xsl:for-each select="//*[value[@animal = 'cat']]">
                <xsl:copy>
                    <xsl:value-of select="@*"/>
                    <xsl:value-of select="'Cat Family'"/>
                </xsl:copy>
            </xsl:for-each>
        </root>
    </xsl:template>
</xsl:stylesheet>

So what have you tried? This is a good task to write your first stylesheet, just start with the identity transformation and then set up the template matching the nodes you want to change and in the template body create the new content you want — Martin Honnen
– Martin Honnen, Commented Feb 20, 2020 at 11:04
Here is the code that works for specified attributes, I need to generalize it. ` <?xml version="1.0" encoding="UTF-8"?> <xsl:stylesheet xmlns:xsl="w3.org/1999/XSL/Transform" exclude-result-prefixes="xsl" version="2.0"> <xsl:template match="/"> <root> <xsl:for-each select="//*[value[@animal = 'cat']]"> <xsl:copy> <xsl:value-of select="@*"/> <xsl:value-of select="'Cat Family'"/> </xsl:copy> </xsl:for-each> </root> </xsl:template> </xsl:stylesheet>` — Amith Bapu
– Amith Bapu, Commented Feb 20, 2020 at 11:45
It is fine that you want to show us your code, but please edit your question and insert it there as a well-formatted code sample so that we have a chance to read it. And as I said, the identity transformation (e.g. declared in XSLT 3 as <xsl:mode on-no-match="shallow-copy"/>) plus a template matching the nodes you want to transform is the right approach. — Martin Honnen
– Martin Honnen, Commented Feb 20, 2020 at 11:58

Amrendra Kumar · Accepted Answer · 2020-02-20 12:33:24Z

3

This is very simple task you need to use identity template to copy of all xml nodes as it is:

<xsl:template match="@* | node()">
    <xsl:copy>
        <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
</xsl:template>

Then you can use a seperate template of value element as per your requirement:

<xsl:template match="value">
    <xsl:choose>
        <xsl:when test="@animal = 'cat'">
            <value animal="cat">Cat Family</value>
        </xsl:when>
        <xsl:when test="@animal = 'dog'">
            <value animal="dog">Dog Family</value>
        </xsl:when>
    </xsl:choose>
</xsl:template>

Final XSL file is :

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" exclude-result-prefixes="xsl" version="2.0">

    <!-- indent elements to see properly -->
    <xsl:output indent="yes"/>

    <xsl:template match="@* | node()">
        <xsl:copy>
            <xsl:apply-templates select="@* | node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="value">
        <xsl:choose>
            <xsl:when test="@animal = 'cat'">
                <value animal="cat">Cat Family</value>
            </xsl:when>
            <xsl:when test="@animal = 'dog'">
                <value animal="dog">Dog Family</value>
            </xsl:when>
        </xsl:choose>
    </xsl:template>

</xsl:stylesheet>

answered Feb 20, 2020 at 12:33

Amrendra Kumar

1,8261 gold badge13 silver badges17 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

Amith Bapu Over a year ago

Thanks, that helps. I will do similarly in my original code.

Martin Honnen · Accepted Answer · 2020-02-20 14:39:31Z

1

In XSLT 3 you can declare the identity transformation with an xsl:mode on-no-match="shallow-copy" as the default processing and then match on value[@animal]:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    exclude-result-prefixes="#all"
    version="3.0">

  <xsl:mode on-no-match="shallow-copy"/>

  <xsl:template match="value[@animal]">
      <xsl:copy>
          <xsl:apply-templates select="@*"/>
          <xsl:value-of select="@animal || ' family'"/>
      </xsl:copy>
  </xsl:template>

</xsl:stylesheet>

https://xsltfiddle.liberty-development.net/94Acsmj

answered Feb 20, 2020 at 14:39

Martin Honnen

169k6 gold badges100 silver badges122 bronze badges

Collectives™ on Stack Overflow

Replace value in a node retaining the XML Structure using XSLT

2 Answers 2

1 Comment

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

1 Comment

Comments

Your Answer

Sign up or log in

Post as a guest

Related