Transformation of Json array in Dataweave

Question

How to write Dataweave transformation in Anytime Studio for given input and output of Json array. Input:

{
    "result": [{
        "Labels": [{
            "value": [{
                    "fieldName": "firstName",
                    "value": "John"
                },
                {
                    "fieldName": "lastName",
                    "value": "Doe"
                },
                {
                    "fieldName": "fullName",
                    "value": "John Doe"
                }
            ]
        }]
    }]
}

Output:

 {
    "result": [{
        "Labels": [{
            "value": [{
                "firstName": "John",
                "lastName": "Doe",
                "fullName": "John Doe"
            }]
        }]
    }]
 }

https://docs.mulesoft.com/dataweave/2.4/dw-core-functions-reduce Reduce function might be the one should be used Thank you in advance

Your input and output json are invalid. What is that you are trying to achieve? — Salim Khan
– Salim Khan, Commented Jul 13, 2022 at 6:33
Should reword the question, the product is "Anypoint Studio". — Ryan Hoegg
– Ryan Hoegg, Commented Jul 19, 2022 at 1:21

Harshank Bansal · Accepted Answer · 2022-07-13 07:03:17Z

2

You can just use map to map all the arrays to required format. For the value part you can map the values as fieldName: value array and deconstruct them to an object by wrapping the array around parentheses

%dw 2.0
output application/json  
---
{
  result: payload.result map ((item) -> {
    Labels: item.Labels map ((label) -> {
      value: [
        {
          (label.value map ((field) -> 
            (field.fieldName): field.value
          )) //wrap the array, i.e. lavel.value map ... in parentheses so that it will give you individual key pair.
        }
      ]
    })
  })
}

answered Jul 13, 2022 at 7:03

Harshank Bansal

3,4202 gold badges11 silver badges30 bronze badges

Sign up to request clarification or add additional context in comments.

3 Comments

richard Over a year ago

"Cannot coerce Array ([]) to Key 16| (field.fieldName): field.value ^^^^^^^^^^^^^^^^^^ got this error

Harshank Bansal Over a year ago

Can you confirm the input that you shared in the question? I rechecked the dataweave here developer.mulesoft.com/learn/dataweave and it is working for me with the input that you have shared

richard Over a year ago

Yes, it was my fault, this works! Thank youI

StackOverflowed · Accepted Answer · 2022-07-13 08:21:15Z

1

You can try below if you are aware that the keyNames will not change:

%dw 2.0
output application/json  
---
payload update {
  case res at .result -> res map (res, resIndex) -> (res update {
      case lbl at .Labels -> lbl map (lbl, lblIndex) -> (lbl update {
          case val at .value -> [
            (val reduce ((item, acc = {}) -> acc ++ {
                (item.fieldName): (item.value)
              }))
          ]
        }
        )
    }
    )
}

answered Jul 13, 2022 at 8:21

StackOverflowed

7593 silver badges7 bronze badges

Comments

Jason Chiu · Accepted Answer · 2022-07-13 06:41:37Z

Here's 2 caveats and a solution. Your input and output files, both are not valid JSON.

Input file, in your "result" object, "Labels" need curly braces {} since they are objects. Key-value pairs should look like this {key:value} not like that key:value
Output file, inside your "value" arrays, key-value pairs need to have the curlies {key:value}

So here's a valid JSON version of your input

{
 "result": [
  {"Labels": [
        {
          "value": [
            {"fieldName": "firstName","value": "John"},
            {"fieldName": "lastName","value": "Doe"},
            {"fieldName": "fullName","value": "John Doe"}
          ]
        }
      ]},
   {"Labels": [
        {
          "value": [
            {"fieldName": "firstName","value": "John"}
          ]
        }
      ]}
]}

Here's a solution

%dw 2.0
import keySet from dw::core::Objects

// this is "result"
var layer1key = keySet(payload)[0]
// this is "Labels" and grabs the first Labels, so assumes Labels doesn't change
var layer2 = payload[layer1key]
var layer2key = keySet(layer2[0])[0]
// this is "value"
var layer3 = layer2[layer2key]
var layer3key = keySet(layer3[0][0])[0]
// this is "fieldName" and "value"
var layer4 = layer3 map (x) -> x['value']

var data1 = ((layer1key) : layer4 map (x) -> {
    (layer2key): x map (y) -> {
        (layer3key): y map (z) -> {
            (z['fieldName']):z['value']
        }
    }
})
output application/json
---
data1

And a valid JSON version of your output

{
  "result": [
    {
      "Labels": [
        {
          "value": [
            {
              "firstName": "John"
            },
            {
              "lastName": "Doe"
            },
            {
              "fullName": "John Doe"
            }
          ]
        }
      ]
    },
    {
      "Labels": [
        {
          "value": [
            {
              "firstName": "John"
            }
          ]
        }
      ]
    }
  ]
}

Collectives™ on Stack Overflow

Transformation of Json array in Dataweave

3 Answers 3

3 Comments

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

3 Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related