Generating a nested functional expression

Question

I was trying to create a functional equivalent via:

q)buildQuery["update rnk:(rnk1+rnk2+rnk3+rnk4)%4 from t"]
"![t;();0b;(enlist`rnk)!enlist (%;(+;`rnk1;(+;`rnk2;(+;`rnk3;`rnk4)));4)]"

Consider the nested functional expression above:

(+;`rnk1;(+;`rnk2;(+;`rnk3;`rnk4)))

How can I generate it procedurally given the list below

`rnk1`rnk2`rnk3`rnk4

You're basically just calculating the average. Why don't you use avg ? — Alexander Unterrainer-DefconQ
– Alexander Unterrainer-DefconQ, Commented Apr 17 at 16:25
It would be helpful to know what buildQuery does or how it's defined — Alexander Unterrainer-DefconQ
– Alexander Unterrainer-DefconQ, Commented Apr 17 at 16:26

terrylynch · Accepted Answer · 2025-04-17 19:13:20Z

3

To answer your question directly, you can generate that construct using:

q){(+;y;x)}/[reverse`rnk1`rnk2`rnk3`rnk4]
+
`rnk1
(+;`rnk2;(+;`rnk3;`rnk4))

Alternatively, use a different formulation of your problem

update rnk:(+/)(rnk1;rnk2;rnk3;rnk4)%4 from t
/or
update rnk:sum(rnk1;rnk2;rnk3;rnk4)%4 from t

where both would parse into a form which would make using that list more direct

![t;();0b;(1#`rnk)!enlist(+/;(%;enlist,`rnk1`rnk2`rnk3`rnk4;4))]
![t;();0b;(1#`rnk)!enlist(sum;(%;enlist,`rnk1`rnk2`rnk3`rnk4;4))]

answered Apr 17 at 19:13

terrylynch

14k1 gold badge15 silver badges23 bronze badges

Sign up to request clarification or add additional context in comments.

1 Answer 1