Perl call a sub routine that exists inside of an array

Question

I am trying to make a state machine in Perl. To do this I have an array indexed by statenames. I can put subs into this array. Like this:

   use constant {
    stInit          => 0,
    stHeader        => 1,
    stSalesHeader   => 2,
    stCatagory      => 3,
    stData          => 4,
    stTotal         => 5,
    stError         => 6, 
};

my $state = stInit;
my @actions;

$actions[stInit] = [sub{logState("Initial state entered",2) }];
$actions[stHeader] = [sub{logState("Header state entered",2) }];
$actions[stSalesHeader] = [sub{logState("Sales header state entered",2) }];
$actions[stCatagory] = [sub{logState("Category state entered",2) }];
$actions[stData] = [sub{logState("Data state entered",2) }];
$actions[stTotal] = [sub{logState("Total state entered",2) }];

But then I have no Idea how to call the subroutine. I have tried this

$actions[$state]

But that appears not to work. Is this possible or am I completely off?

Borodin · Accepted Answer · 2012-01-20 02:35:54Z

9

You really should add

use strict;
use warnings;

to the start of your code, which will find many simple mistakes for you. In this case your code is fine, and you can call your subroutines by using

$actions[$state][0]();

etc.

But there is no need to put the subroutines within square brackets, which just creates a one-element anonymous array and adds an additional level of indexing (hence the [0] in the above line of code. If you wrote code like this instead

$actions[stInit] = sub { logState("Initial state entered", 2) };

then you would be able to call the subroutines with

$actions[$state]();

edited Jan 20, 2012 at 2:35

answered Jan 20, 2012 at 2:27

Borodin

127k9 gold badges72 silver badges146 bronze badges

Sign up to request clarification or add additional context in comments.

7 Comments

mu is too short Over a year ago

Using () nicely avoids accidentally inheriting @_ as well, using & is a bad habit IMO.

Borodin Over a year ago

Indeed. The only non-esoteric use for & is to access a reference to a subroutine using \&mysub. It has been this way for many years.

ikegami Over a year ago

@Borodin, Like $ref->(), &$ref() doesn't inherit @_ either.

ikegami Over a year ago

@Borodin, & is also useful for disabling prototypes. (e.g. &async($sub)).

ikegami Over a year ago

@Borodin, & is also used in goto ⊂, defined &sub and exists &sub.

|

Ovid · Accepted Answer · 2012-01-20 13:34:57Z

2

On an a slightly different note, have you considered using FSA::Rules to write your state machine? It's fairly powerful, has optional GraphViz output and makes state machines rather easy to write.

answered Jan 20, 2012 at 13:34

Ovid

11.7k9 gold badges50 silver badges76 bronze badges

Comments

xpapad · Accepted Answer · 2012-01-20 02:24:08Z

1

You should do:

&{$actions[$state][0]}

but I'm not sure why you use an array... If you have just 1 function then

$actions[stData] = sub{ ... }
...
&{$actions[$state]}

will work. If you really want to execute many functions and use the array, then you can do:

map { &{$_}  } @{$actions[$state]};

answered Jan 20, 2012 at 2:24

xpapad

4,4761 gold badge26 silver badges26 bronze badges

1 Comment

Borodin Over a year ago

Yet again, as for the other two answers, use $actions[$state]() in all but very old versions of Perl. Also you are committing the sin of using map for its side-effects and discarding the result. If you want to do this then you just need $_->() foreach @{$actions[$state]};

Jarmund · Accepted Answer · 2012-01-20 02:29:50Z

1

To call a subroutine from a reference:

&{$actions[$state]}();

However, based on your code, @actions does not contain subroutine references, but array references to the declaration of the subroutine.

first, declare the subs as you normally would and then build @actions:

$actions[0] = \&stInit;
$actions[1] = \&stHeader;
...and so on

edited Jan 20, 2012 at 2:29

answered Jan 20, 2012 at 2:24

Jarmund

3,2454 gold badges25 silver badges49 bronze badges

1 Comment

Borodin Over a year ago

The use of an ampersand when calling subroutines is old-fashioned and very bad practice. Just $actions[$state]() is fine.

zgpmax · Accepted Answer · 2012-01-21 20:15:58Z

Drop the extraneous anonymous array creation by removing the square brackets

$actions[stInit] = sub{logState("Initial state entered",2) };

You can then call the action with

$actions[stInit]();

If you have an action stored in a variable, e.g.

my $action = $actions[$actionID];

then you'll need a bit more syntax to make it actually do the call

$action->();

Then again, you could just use a hash instead of an array

my %actions = (
    stInit        => sub { logState("Initial state entered",2) },
    stHeader      => sub { logState("Header state entered",2) },
    stSalesHeader => sub { logState("Sales header state entered",2) },
    stCatagory    => sub { logState("Category state entered",2) },
    stData        => sub { logState("Data state entered",2) },
);

which would save you from having to set up constants at the top. You could then call actions with

$actions{$state}();

Collectives™ on Stack Overflow

Perl call a sub routine that exists inside of an array

5 Answers 5

7 Comments

Comments

1 Comment

1 Comment

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

5 Answers 5

7 Comments

Comments

1 Comment

1 Comment

Comments

Your Answer

Sign up or log in

Post as a guest

Related