Search an array for a string and return the index in AS3

Question

I want to search an array to see if it contains a specific string, and then get the index of the result.

For example, if I had:

array[0] = "dogs";
array[1] = "cats";
array[2] = "oranges";

I want to be able to search for "oran" and get 2 back. Any idea on how to do this?

ToddBFisher · Accepted Answer · 2012-01-20 21:33:04Z

4

You can do something like this:

function findInArray(str:String):int {
    for(var i:int = 0; i < array.length; i++){
        if(array[i] == str){
            trace("found it at index: " + i);
            return i;
        }
    }
    return -1; //If not found
}

Then whenever you want to find something call it like:

findInArray("oranges"); // Returns 2

To search for a part of the word can pontentially return undesiderd results for bigger lists, but you can do it with the following:

function findInArrayPartially(str:String):int {
    for(var i:int = 0; i < array.length; i++){
        if(array[i].indexOf(str) > -1){
            trace("found it at index: " + i);
            return i;
        }
    }
    return -1; //If not found
}

edited Jan 20, 2012 at 21:33

answered Jan 20, 2012 at 21:22

ToddBFisher

11.6k9 gold badges43 silver badges58 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

adamzwakk Over a year ago

I saw this, but I want to find a string inside a string. Like if I gave it just "orang" it would still give back 2 because "orang" is part of "oranges"

ToddBFisher Over a year ago

see my edit, I just changed a line to essentially search for the string

arhonthhh · Accepted Answer · 2013-07-17 14:34:33Z

1

Another way to do it:

var arr:Array = ["dogs", "cats", "oranges", "apples"];

function indexOfSubstring(array:Array, stringToFind:String):int
{
    var answer:int = array.indexOf(stringToFind);

    if (answer == -1)
    {
        var separator:String = "|";
        var arrayToString:String = array.join(separator);
        var indexInString:int = arrayToString.indexOf(stringToFind);

        if (indexInString != -1)
        {
            var shorterStr:String = arrayToString.substring(0, indexInString);
            answer = shorterStr.split(separator).length - 1;
        }
    }

    return answer;
}

trace(indexOfSubstring(arr, "oran")); // returns 2
trace(indexOfSubstring(arr, "les")); // returns 3
trace(indexOfSubstring(arr, "ts")); // returns 1
trace(indexOfSubstring(arr, "broom")); // returns -1

edited Jul 17, 2013 at 14:34

answered Jul 16, 2013 at 8:54

arhonthhh

2372 silver badges9 bronze badges

1 Comment

Nate914375 Over a year ago

while this can work in cases where you know what may be in the strings, it can give invalid results if the strings in your array had the separator character in them.

Collectives™ on Stack Overflow

Search an array for a string and return the index in AS3

2 Answers 2

2 Comments

1 Comment

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

2 Comments

1 Comment

Your Answer

Sign up or log in

Post as a guest

Related