Sort an array in perl

Question

I have an array with elements

@a =(mem_64x128,mem_8x64,mem_8x128,mem_128x64);

I want the array to be sorted in the following manner

   mem_8x64,mem_8x128,mem_64x128,mem_128x64

But when I sort @a, the output I get is

mem_128x64
mem_64x128
mem_8x64
mem_8x128

Can anyone please help. Thanks

It is because when sorting alphabetically 128 comes before 64. You might be interested in this: stackoverflow.com/q/19544253/725418 — TLP
– TLP, Commented Oct 25, 2013 at 10:15
The same way. You sort a list of elements, not a data structure. — TLP
– TLP, Commented Oct 25, 2013 at 11:15

Suic · Accepted Answer · 2013-10-25 11:34:03Z

4

Use custom comparing function sort (perldoc):

sort {
   my ($c,$d) = $a =~ /(\d+)x(\d+)/;
   my ($e,$f) = $b =~ /(\d+)x(\d+)/;
   $c<=>$e || $d<=>$f;
} @a;

or faster one:

my %h;
@a = sort  {
   $h{$a} || ( @{$h{$a}} = $a =~ /(\d+)x(\d+)/ );
   $h{$b} || ( @{$h{$b}} = $b =~ /(\d+)x(\d+)/ );
   $h{$a}->[0] <=> $h{$b}->[0] || $h{$a}->[1] <=> $h{$b}->[1];
} @a;

edited Oct 25, 2013 at 11:34

answered Oct 25, 2013 at 10:42

Suic

2,5112 gold badges19 silver badges31 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

Mark Setchell · Accepted Answer · 2013-10-25 10:24:07Z

3

Try something like this:

#!/usr/bin/perl
use strict;
use warnings;

my @a =("mem_64x128","mem_8x64","mem_8x128","mem_128x64");

print sort byFirst sort bySecond @a;

sub byFirst{
# Extract first number from a
my $y=$a;
$y =~ s/.*_//;
$y =~ s/x.*//;

# Extract first number from b
my $z=$b;
$z =~ s/.*_//;
$z =~ s/x.*//;
return $y <=> $z;
}

sub bySecond{
# Extract second number from a
my $y=$a;
$y =~ s/.*x//;

# Extract second number from b
my $z=$b;
$z =~ s/.*x//;
return $y <=> $z;
}

answered Oct 25, 2013 at 10:24

Mark Setchell

210k32 gold badges309 silver badges503 bronze badges

Comments

Slaven Rezic · Accepted Answer · 2013-10-26 20:12:51Z

2

This is another use case where the nsort function from the CPAN module Sort::Naturally works as humans expect it:

@a =(mem_64x128,mem_8x64,mem_8x128,mem_128x64); # no strict!
use Sort::Naturally qw(nsort);
print join(',', nsort @a), "\n";

Output is:

mem_8x64,mem_8x128,mem_64x128,mem_128x64

answered Oct 26, 2013 at 20:12

Slaven Rezic

4,58116 silver badges12 bronze badges

Comments

edi_allen · Accepted Answer · 2013-10-25 11:23:26Z

2

Here is one way to do it.

use warnings;
use strict;


my @a = ('mem_64x128', 'mem_8x64', 'mem_8x128', 'mem_128x64');

my @sorted_a = sort { (split /[_x]/, $a)[1] <=> (split /[_x]/, $b)[1]
                           or
          (split /[_x]/, $a)[2] <=> (split /[_x]/, $b)[2]
} @a;

print "$_\n" foreach @sorted_a;

OUTPUT

mem_8x64
mem_8x128
mem_64x128
mem_128x64

edited Oct 25, 2013 at 11:23

answered Oct 25, 2013 at 10:51

edi_allen

1,9021 gold badge11 silver badges8 bronze badges

2 Comments

TLP Over a year ago

/_|x/ is better written /[_x]/.

edi_allen Over a year ago

@TLP Thanks for the observation. I fixed it.

mpapec · Accepted Answer · 2013-10-25 10:58:22Z

1

Elements are sorted by first, and second number in ascending order,

my @r = qw(mem_64x128 mem_8x64 mem_8x128 mem_128x64);

@r = map { $_->[0] }
  sort {
    $a->[1] <=> $b->[1] || $a->[2] <=> $b->[2]
  }
  map { [$_, /(\d+)/g ] } @r;

print "@r\n";

output

mem_8x64 mem_8x128 mem_64x128 mem_128x64

answered Oct 25, 2013 at 10:58

mpapec

50.7k8 gold badges71 silver badges132 bronze badges

Collectives™ on Stack Overflow

Sort an array in perl

5 Answers 5

Comments

Comments

Comments

2 Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

5 Answers 5

Comments

Comments

Comments

2 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related