Array sorting in Perl

Question

I am new to Perl and stuck with a (likely simple) array sorting problem.

I've inherited some Perl code that reads lines from a text file into three 1-D arrays (x,y,z). I'd like to be able sort these arrays using one of the dimensions as the key and reordering the other two dimensions to match.

For example, if my input is:

@x = (1, 3, 2)
@y = (11,13,12)
@z = (21,23,22)

and I sort by x, I'd like the result to be:

@x = (1, 2, 3)
@y = (11,12,13)
@z = (21,22,23)

I could merge the three 1-D arrays into a 2-D array if that makes life easier.

your example data could be cleared - the values in @y and @z are in the same order as @x. having very different values (or even something like 'a','b','c') would make it clearer exactly how they are to be sorted — plusplus
– plusplus, Commented Jan 5, 2011 at 17:57

mob · Accepted Answer · 2011-01-05 16:14:41Z

10

Merging all the arrays together isn't necessary. Use sort to get the correct index ordering for the elements in @x:

@sort_by_x = sort { $x[$a] <=> $x[$b] } 0 .. $#x;    #   ==> (0, 2, 1)

Then apply that index ordering to any other array:

@x = @x[@sort_by_x];
@y = @y[@sort_by_x];
@z = @z[@sort_by_x];

edited Jan 5, 2011 at 16:14

answered Jan 5, 2011 at 15:59

mob

119k18 gold badges159 silver badges291 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

zakovyrya · Accepted Answer · 2011-01-05 15:23:29Z

3

use strict;
use warnings;
use Data::Dumper;

use List::Util qw(reduce);

my @x = (1, 3, 2);
my @y = (11, 13, 12);
my @z = (21, 23, 22);

my @combined = map { [ $x[$_], $y[$_], $z[$_] ] } 0 .. $#x;
my @sorted = sort { $a->[0] <=> $b->[0] } @combined;
my $split_ref = reduce { push @{$a->[$_]}, $b->[$_] for 0 .. $#$a; $a;} [[], [], []], @sorted;

print Dumper \@combined;
print Dumper \@sorted;
print Dumper $split_ref;

Which will essentially give you:

answered Jan 5, 2011 at 15:23

zakovyrya

9,7196 gold badges41 silver badges28 bronze badges

Comments

Matt K · Accepted Answer · 2011-01-05 15:16:41Z

0

Merging indeed may make life easier.

@sorted = sort { $a->[0] <=> $b->[0] } 
    ( [$x[0], $y[0], $z[0]], [$x[1], $y[1], $z[1]], [$x[2], $y[2], $z[2]] );

might do it. You'll of course not want to write all that out by hand!

answered Jan 5, 2011 at 15:16

Matt K

14k3 gold badges36 silver badges54 bronze badges

Comments

Hugmeir · Accepted Answer · 2011-01-05 15:18:43Z

0

If @x is the same size as @y and @z, there is no need to sort - You can use an array slice instead!

use strict;
use warnings;
use 5.010;

my @x = (1, 3, 2);
my @y = (11,13,12);
my @z = (21,23,22);

say join ', ', @y;
@y = @y[ map { $_ - 1 } @x ]; #We use map create a lists of the values of elements in @x, minus 1.
say join ', ', @y;

Of course, if you just want to sort by numerical order, then using @x is superfluous:

@y = sort { $a <=> $b } @y;

Finally, if you want to sort an arbitrary number of arrays, you could create an array of arrays, or pass a list of references to a for, ala

my @indexes = map { $_ - 1 } @x;

for my $array_ref ( \@x, \@y, \@z ) {
    @$array_ref = @{$array_ref}[@indexes];
}

answered Jan 5, 2011 at 15:18

Hugmeir

1,2596 silver badges9 bronze badges

4 Comments

Matt K Over a year ago

I don't think you can safely assume that values in @x can be used as indices. What if they're negative or not unique?

Hugmeir Over a year ago

Negative numbers or repeats wouldn't really be troublesome (it's his spec, after all..), but an index outside of the array will trigger warnings. But yeah, caveat programmer.

Matt K Over a year ago

They are troublesome in that they will give you incorrect results without a warning. Try changing the unsorted @x to (1,3,3).

Hugmeir Over a year ago

Again, his spec - From the OP: "and i sort by x" I took this to mean that he isn't simply sorting the arrays numerically.

Toto · Accepted Answer · 2011-01-05 15:26:22Z

0

Have a try with:

#!/usr/bin/perl 
use 5.10.1;
use strict;
use warnings;
use Data::Dumper;

my @x = (1, 3, 2);
my @y = (11,13,12);
my @z = (21,23,22);

my (%y, %z);

@y{@x} = @y;
@z{@x} = @z;

my @xs = sort @x;
my @ys = @y{@xs};
my @zs = @z{@xs};
say Dumper \@xs,\@ys,\@zs;

Output:

answered Jan 5, 2011 at 15:26

Toto

91.7k63 gold badges97 silver badges135 bronze badges

1 Comment

Matt K Over a year ago

This breaks if @x has any duplicate values.

Peter Mortensen · Accepted Answer · 2017-04-29 02:38:20Z

-1

Do

@a = sort { $a <=> $b } @a;

Also see sort on perldoc.

edited Apr 29, 2017 at 2:38

Peter Mortensen

31.4k22 gold badges110 silver badges134 bronze badges

answered Jan 5, 2011 at 15:12

Benoit

79.7k24 gold badges226 silver badges241 bronze badges

2 Comments

Matt K Over a year ago

That won't sort @y or @z.

amb Over a year ago

yes, that will sort one of the 1-d arrays. it won't sort the other two to match. my hope is to be able to sort by the x array and have the y and z array reordered to match so that the lines from the text file are preserved. i'm sorry if my question wasn't clear. --amb

Collectives™ on Stack Overflow

Array sorting in Perl

6 Answers 6

Comments

Comments

Comments

4 Comments

1 Comment

2 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

6 Answers 6

Comments

Comments

Comments

4 Comments

1 Comment

2 Comments

Your Answer

Sign up or log in

Post as a guest

Related