Custom array sort in perl

Question

I have a perl array of to-do tasks that looks like this:

@todos = (
  "1 (A) Complete online final @evm4700 t:2010-06-02",
  "3 Write thank-you t:2010-06-10",
  "4 (B) Clean t:2010-05-30",
  "5 Donate to LSF t:2010-06-02",
  "6 (A) t:2010-05-30 Pick up dry cleaning",
  "2 (C) Call Chris Johnson t:2010-06-01"
);

That first number is the task's ID. If a task has ([A-Z]) next to, that defines the task's priority. What I want to do is sort the tasks array in a way that places the prioritized items first (and in order of descending priority, from A - Z):

@todos = (
  "1 (A) Complete online final @evm4700 t:2010-06-02",
  "6 (A) t:2010-05-30 Pick up dry cleaning",
  "4 (B) Clean t:2010-05-30",
  "2 (C) Call Chris Johnson t:2010-06-01"
  "3 Write thank-you t:2010-06-10",
  "5 Donate to LSF t:2010-06-02",
);

I cannot use a regular sort() because of those IDs next to the tasks, so I'm assuming that some sort of customized sorting subroutine is needed. However, my knowledge of how to do this efficiently in perl is minimal.

Thanks, all.

Sean · Accepted Answer · 2010-05-30 18:50:21Z

14

Sounds like you want the Schwartzian transform:

@todos =
    map  { $_->[0] }
    sort { $a->[1] cmp $b->[1] or $a->[0] cmp $b->[0] }
    map  { [ $_, /^\d+ \(([[:alpha:]])\)/ ? $1 : "[" ] }
    @todos;

"[" is the character after "Z"; giving this "priority" to otherwise unprioritized items will sort them after the prioritized items.

Alternately, and perhaps more easily graspable:

@todos =
    map { substr $_, 1 }
    sort
    map { (/^\d+ \(([[:alpha:]])\)/ ? $1 : "[") . $_ }
    @todos;

edited May 30, 2010 at 18:50

answered May 30, 2010 at 18:32

Sean

30k5 gold badges85 silver badges111 bronze badges

Sign up to request clarification or add additional context in comments.

7 Comments

Zaid Over a year ago

@Sean : While a Schwartzian transform is groovy (and applicable), it's very hard to follow, especially given that the OP is a beginner.

ABach Over a year ago

@Sean - this is a cool solution; thank you. Do you need to escape that ] ater :alpha:? @Zaid - even though I am a beginner, @Sean gave me that link that explains the Schwartzian transform, so I can understand it. :)

Sean Over a year ago

@ABach: No, no escaping needed; this is a POSIX character class. (See the perlre man page.) ...But I did make a typo ("[:alpha:]]" instead of "[[:alpha:]]", which I just fixed.

jfs Over a year ago

10 should go after 9 (you need numerical sort)

Zaid Over a year ago

@ABach : It's fine by me if it's fine by you! Just remember that Perl doesn't have to be so hard to follow...

|

darch · Accepted Answer · 2010-05-30 19:54:25Z

3

Here's a version that is fairly explicit about how it works:

my @sorted_todos = sort {
    my ($right_prio) = ($b =~ /^\d+\s+\(([A-Z])\)/);
    return -1 unless defined $right_prio;
    my ($left_prio) = ($a =~ /^\d+\s+\(([A-Z])\)/);
    return 1 unless defined $left_prio;
    return $left_prio cmp $right_prio;
} @todos;

answered May 30, 2010 at 19:54

darch

4,3281 gold badge23 silver badges23 bronze badges

Comments

Community · Accepted Answer · 2017-05-23 11:48:56Z

0

Here's fixed @Sean's solution that uses numerical sort for task IDs (thus 10th task goes after 9th as it should):

my @sorted_todos =  map  { $_->[0] }
    sort { $a->[1][1] cmp $b->[1][1] # A
                       || 
           $a->[1][0] <=> $b->[1][0] # 1
    } map  { [ $_, /^(\d+) \(([[:alpha:]])\)/ ? [$1, $2] : [0, "zz"]] }  @todos;

edited May 23, 2017 at 11:48

CommunityBot

11 silver badge

answered May 30, 2010 at 19:27

jfs

417k210 gold badges1k silver badges1.7k bronze badges

2 Comments

rjh Over a year ago

For something this minor, editing Sean's answer seems sufficient. You're not exactly lacking for rep.

jfs Over a year ago

@rjh: read comments to Sean's answer the OP doesn't want the solution I provided so It would be wrong on my part to edit Sean's answer. On the other hand my answer is useful for others who would search for "custom sort in perl" in the future.

salva · Accepted Answer · 2011-01-17 15:34:28Z

0

use Sort::Key 'keysort';

my @sorted = keysort { /^\d+\s+\(([A-Z])\)/ ? $1 : 'ZZ' } @todos;

answered Jan 17, 2011 at 15:34

salva

10.3k4 gold badges31 silver badges61 bronze badges

Comments

user3999721 · Accepted Answer · 2014-09-02 09:43:38Z

0

Much simpler solution:

sort {($a =~ /\((.)\)/)[0] cmp ($b =~ /\((.)\)/)[0]} @todos;

answered Sep 2, 2014 at 9:43

user3999721

Collectives™ on Stack Overflow

Custom array sort in perl

5 Answers 5

7 Comments

Comments

2 Comments

Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

5 Answers 5

7 Comments

Comments

2 Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related