Perl array element manipulation

I think you should post your earlier attempts. In my opinion, the best way to learn is to learn from your mistakes, not being presented a correct solution.

For this problem, I think I would use a C-style for-loop for the first part, simply because it is straightforward, and can easily be tweaked if some new requirement comes up.

The second problem can easily be solved using a regular Perl-style for-loop.

use strict;
use warnings;   # always use these two pragmas

my @nums = 1..6; 
my @idx;
for (my $n = 0; $n <= $#nums; $n += 2) {    # loop from 0 to max index, step 2
    push @idx, $n;                          # store number in @idx
}
print "Indexes: @idx\n"; 

my @diff;
for my $n (0 .. $#nums - 1) {               # loop from 0 to max index minus 1
    push @diff, $nums[$n + 1] - $nums[$n];  # store diff in @diff
}
print "Diff: @diff\n";

Output:

Indexes: 0 2 4
Diff: 1 1 1 1 1

Try this:

use strict;
use warnings;

my $index = 1;
my @a = (1,2,3,4,5,6);
for (@a) {
    if ($index % 2 == 0) {
        my $diff = $_ - $a[$index-2];
        print $diff;
    }
$index++;
}

You likely want to use the new List::Util pair functions.

For your first question:

use List::Util 'pairvalues';

my @seconds = pairvalues @list;  # yields (2, 4, 6)

For your second question:

use List::Util 'pairmap';

my @diffs = pairmap { $b-$a } @list;  # yields (1, 1, 1)

You can use map:

my @a = 1 .. 6;
print join ' ', 'Every second:', map $a[ 1 + $_ * 2 ], 0 .. $#a / 2;
print "\n";
print join ' ', 'Differences:', map $a[ 1 + $_ * 2 ] - $a[ $_ * 2 ], 0 .. $#a / 2;
print "\n";

First: Don't use variables a and b. $a and $b are special variables used in sorting. Just be a bit more descriptive of your variables (even if it's merely @my_array) and you should be fine.

You can loop through your array any which way you like. However, I prefer to use a while loop instead of the thee part for because the three part for loop is a bit misleading. It is a while loop in disguise and the promised indexing of the loop can be misleading.

#! /usr/bin/env perl
use warnings;
use strict;
use feature qw(say);

my @array = qw( 1 2 3 4 5 6 );
my $index = 1;      # Remember Perl indexes start at zero!
while ( $index <= $#array ) {
    say "Item is $array[$index]";
    say "The difference is " . ($array[$index] - $array[$index-1]);
    $index += 2;
}

You said every second element. Indexes of arrays start at 0, so you want the odd number elements. Most of the answers use map which is a very nice little command, but does an awful lot in a single line which can make it confusing for a beginner. Plus, I don't think the Perldoc on it is very clear. There should be more simple examples.

The say is a newer version of print. However say always adds a \n at the end. You should always use strict; and use warnings;. These will catch about 90% of your programming bugs.

The qw( ... ) is a quick way to make an array. Each word becomes an array element. You don't need quotes or commas.

#!/usr/bin/perl
use strict;
use warnings;

my @ar = (1, 2, 3, 4, 5, 6);

# 1. How do I get every second index ( 2, 4, 6) in this case?
my @even = map { $_ & 1 ? $ar[$_] : () } 0 .. $#ar;

# 2. how do I compute the difference of every two elements?
my (@c, @diff) = @ar;
push @diff, -1 * (shift(@c) - shift(@c)) while @c;

use Data::Dumper;
print Dumper \@even;
print Dumper \@diff;

1;

__END__
$VAR1 = [
          2,
          4,
          6
        ];
$VAR1 = [
          1,
          1,
          1
        ];